@echo off

REM This batch file will launch four separate copies of WPDOS under Windows.
REM Edit the following four lines so that wpdrv is the drive letter with WP;
REM wpdir is the directory that contains WP (starting with a backslash);
REM wpver is either 5 or 6, depending on whether you use WPDOS 5.x or 6.x;
REM and wpparam includes any command-line switches that you use with WP,
REM for example: /DL /NS [etc.]

set wpdrv=c:
set wpdir=\wp51
set wpver=5
set wpparam= 

REM Do not modify anything below this line unless you are absoutely certain
REM that you know what you are doing.

if %wpver%==5 set chk=wp}wp{.chk
if %wpver%==6 set chk=wp}wpc{.chk
%wpdrv%
cd %wpdir%
if not exist tmpdir00 md tmpdir00
if not exist tmpdir01 md tmpdir01
if not exist tmpdir02 md tmpdir02
if exist %chk% goto use00
start "WordPerfect North" wp.com %wpparam%
goto end
:use00
if exist tmpdir00\%chk% goto use01
start "WordPerfect South" wp.com /d-%wpdrv%%wpdir%\tmpdir00 %wpparam%
goto end
:use01
if exist tmpdir01\%chk% goto use02
start "WordPerfect East" wp.com /d-%wpdrv%%wpdir%\tmpdir01 %wpparam%
goto end
:use02
if exist tmpdir02\%chk% goto :limit
start "WordPerfect West" wp.com /d-%wpdrv%%wpdir%\tmpdir02 %wpparam%
goto end
:limit
command /k echo Too many copies of WP are open. Enter "Exit" to close this window.
:end