cap log close
log using rd, replace
set more off

/******************************************************************************
Regression Discontinuity and the Price Effects of Stock Market Indexing
Yen-Cheng Chang, Harrison Hong, and Inessa Liskovich

This program runs the basic RD regression. Because it is a fuzzy RD we use 
2SLS. We run the regression separately for stocks starting in the Russell 1000
and Russell 2000. We show the results for four different bandwidth options and 
two different specifications (linear or quadratic trends on either side of the
discontinuity). Our outcome variable is returns (ret) but can easily be changed 
to any other outcome of interest.
******************************************************************************/

/* Use the sample of firms around the upper cut-off every year */
use rdsampleall, clear

/* Create different bandwidths to test */
gen byte b300=rank>=-300 & rank<=300
gen byte b200=rank>=-200 & rank<=200
gen byte b100=rank>=-100 & rank<=100
gen byte b50=rank>=-50 & rank<=50
global bw 300 200 100 50

/* Run separate RD for firms starting in the Russell 1000 and Russell 2000 */
forval r=1/2{
/* Run the specification for every bandwidth */
foreach b of global bw {

/* Check returns results for May - September */
forval m=3/9 {
/* Fuzzy RD with linear trends in rank on either side of the cutoff */
ivregress 2sls ret (r2j rankd = inc rankinc) rank if month==`m' & b`b'==1 & rm==`r', r  
/* Fuzzy RD with quadratic trends in rank on either side of the cutoff */
ivregress 2sls ret (r2j rankd rank2d = inc rankinc rank2inc) rank rank2 if month==`m' & b`b'==1 & rm==`r', r  
}

}
}


/******************************************************************************
Notes on variables:

r2j is an indicator variable for membership in the Russell 2000 in June. In the 
	equations in the paper it is the variable "D"
inc is a indicator variable for being below the threshold for inclusion in the 
	Russell 2000 in June. It is our instrument for actual inclusion, r2j. In the
	equations in the paper it is the variable "tau"
rankd is rank interacted with "D"
rankinc is rank interacted with "tau"
rank2 is rank^2
rank2d is rank^2 interacted with "D"
rank2inc is rank^2 interacted with "tau"
******************************************************************************/


log close